Divergenza del fascio gaussiano

Manipulate[
Plot[{w0 Sqrt[1+(2z/w0^2)^2],-w0 Sqrt[1+(2z/w0^2)^2]},{z,0,2},PlotRange->{-4,4}, ImageSize->500]
,{{w0,1,"w0"},0.1,3,.1},ControlPlacement->Left]

Focalizzazione del fascio gaussiano

Manipulate[z0=1/(1+4/w^4);w0=w/Sqrt[1+w^4/4];
Plot[{w0 Sqrt[1+(2(z-z0)/w0^2)^2],-w0 Sqrt[1+(2(z-z0)/w0^2)^2]},{z,0,2},PlotRange->{-12,12}, ImageSize->500]
,{{w,10,"w"},0.2,10,.1},ControlPlacement->Left]

Profilo HG (1D)

xmax=5;
indicemax=10;
lista=Table[i,{i,0,indicemax}];
Manipulate[
Plot[HermiteH[n,Sqrt[2]x] Exp[-x^2],{x,-xmax,xmax},PlotRange->All, ImageSize->500]
,Control[{{n,0},lista}],ControlPlacement->Left]

Profilo HG (2D)

indicemax=10;
lista=Table[i,{i,0,indicemax}];
gamma=0.7;
Manipulate[
DensityPlot[Abs[HermiteH[n,Sqrt[2]x]HermiteH[m,Sqrt[2]y] Exp[-x^2-y^2] ]^(2gamma),{x,-3,3},{y,-3,3},PlotPoints->50,ColorFunction->GrayLevel, ImageSize->350,Frame->False,PlotRange->All]
,Control[{{n,0},lista}],Control[{{m,0},lista}],ControlPlacement->Left]

Propagazione modo puro vs combinazione di modi

gamma=0.7;

Manipulate[
Row[{
Column[{"x^2 Exp[-r^2]",
DensityPlot[Abs[((8 x^2/(1+z^2) - 2)Exp[-2 I ArcTan[z]]+2) Exp[-(x^2+y^2)/(1+z^2)] ]^(2gamma),{x,-5,5},{y,-5,5},PlotPoints->50,ColorFunction->GrayLevel, ImageSize->350,Frame->False,PlotRange->All]
}],
Column[{"x Exp[-r^2] = HG10",
DensityPlot[Abs[HermiteH[1,Sqrt[2/(1+z^2)]x]HermiteH[0,Sqrt[2/(1+z^2)]y] Exp[-(x^2+y^2)/(1+z^2)]]^(2gamma),{x,-5,5},{y,-5,5},PlotPoints->50,ColorFunction->GrayLevel, ImageSize->350,Frame->False,PlotRange->All]
}]
}]
,{{z,0,"z"},0,2,.01},ControlPlacement->Left]

Profilo LG (dip. da r)

xmax=5;
indicemax=10;
lista=Table[i,{i,0,indicemax}];
Manipulate[
Plot[(Sqrt[2r^2])^Abs[s]  LaguerreL[p,s,2r^2] Exp[-r^2] ,{r,0,xmax},PlotRange->All, ImageSize->500]
,Control[{{p,0},lista}],Control[{{s,0},lista}],ControlPlacement->Left]

Profilo LG

indicemax=10;
lista=Table[i,{i,0,indicemax}];
gamma=0.7;
Manipulate[
Row[{
Column[{"Intensità",
DensityPlot[Abs[(Sqrt[2(x^2+y^2)])^Abs[s]  LaguerreL[p,s,2(x^2+y^2)] Exp[-x^2-y^2] ]^(2gamma),{x,-3,3},{y,-3,3},PlotPoints->50,ColorFunction->GrayLevel, ImageSize->350,Frame->False,PlotRange->All]
}],
Column[{"Fase",
DensityPlot[Arg[Exp[I (s ArcTan[x,y]+Pi)]],{x,-3,3},{y,-3,3},PlotPoints->50,ColorFunction->GrayLevel, ImageSize->350,Frame->False,PlotRange->All]
}]
}]
,Control[{{p,0},lista}],Control[{{s,0},lista}],ControlPlacement->Left]

Onda piana + LG

dimimm=300;
xmax=2;
indicemax=10;
lista=Table[i,{i,0,indicemax}];
gamma=0.7;
Manipulate[
Row[{
Column[{"Solo Laguerre",
DensityPlot[Abs[(Sqrt[2(x^2+y^2)])^Abs[s]  LaguerreL[p,s,2(x^2+y^2)] Exp[-x^2-y^2] ]^(2gamma),{x,-xmax,xmax},{y,-xmax,xmax},PlotPoints->50,ColorFunction->GrayLevel, ImageSize->dimimm,Frame->False,PlotRange->All]
}]
,
Column[{"Con fascio di riferimento",
DensityPlot[Abs[(Sqrt[2(x^2+y^2)])^Abs[s]  LaguerreL[p,s,2(x^2+y^2)] Exp[-x^2-y^2]Exp[I (s ArcTan[x,y])]+A Exp[I kx x]]^(2gamma),{x,-xmax,xmax},{y,-xmax,xmax},PlotPoints->{50,50},ColorFunction->GrayLevel,Frame->False, ImageSize->dimimm,PlotRange->{0,2}]
}]
}]
,{{A,0},0,1,.1},{{kx,0},0,20,1},Control[{{p,0},lista}],Control[{{s,0},lista}],ControlPlacement->Left]