Script Gnuplot per graficare l'istogramma di frequenze dei dati nel file peso.dat
Salvare il file peso.dat in una directory e i comandi dello script in un file (Es. istogramma.txt) nella stessa directory. Caricare lo script in Gnuplot usando il tasto Open (windows) oppure con il comando: load 'istogramma.txt'

# definisce la funzione classe:
# a= ampiezza delle classi
# per ogni x calcola il valore della classe corrispondente
# e definisce il centro dell'intervallo come ascissa
#
classe(x, a) = a*int(x/a) + a/2.

#definisce la larghezza della classe
a = 2.

# larghezza colonne dell'istogramma
set boxwidth a/2.

set title " Frequenze assolute dei pesi "
set xlabel " Pesi [g]"
set ylabel " Frequenze ass."

# numero totale di punti
# se Nt = 1 frequenze assolute
Nt = 1

#grafico
#inserisci tra parentesi i limiti per il grafico

plot [:][0:10] 'peso.dat' u ( classe($2,a) ):(1./Nt) smooth frequency t '' w boxes

pause -1 'premi return per il grafico delle frequenze relative'

Nt=30

set title " Frequenze relative dei pesi "
set xlabel " Pesi [g]"
set ylabel " Frequenze rel. "

plot [:][0:0.4] 'peso.dat' u ( classe($2,a) ):(1./Nt) smooth frequency t '' w boxes